You bought an Android phone because you want to start developing a cool flash or AIR App for that device?
Or you just wondering how easy it is to develop an application for those target devices?

In the following series, I’m going to show you how to access those special properties that are available when developing for an Android or any other Flash / AIR powered device.

Today, we start with the Accelerometer API.

In this article I’m going to show you how to control a simple ball with the help of the accelerometer API. Clearly you could create a game like the well known Labyrinth available for the iOS or Teeter available on the HTC android devices very easy as soon as you know how to master the Accelerometer API.

Before we start just a heads up that you can follow this article even if you work with Flash CS5 although working with Flash Builder “Burrito” makes your life much easier.

To start let’s create a new Flash Builder “actionscript mobile project” called: “AccelerometerBall“.  Setup the project how you like it, just be sure that you enable full screen.

Now that you are ready to go we first check if an accelerometer is available, if none is available then it’s not worth of continuing the game, but if it’s available we add the sphere to the stage which we want to control. You can add whatever you want, i’m just using a simple sphere I created in Photoshop to be my indicator.

if ( Accelerometer.isSupported )
{
    _accelerometer = new Accelerometer();
    _accelerometer.addEventListener( AccelerometerEvent.UPDATE, onAccelUpdate );
 
    _sphere = new sphereClass();
    _sphere.scaleX = _sphere.scaleY = .2;
    addChild( _sphere );
 
    addEventListener(Event.ENTER_FRAME, moveSphere );
}
else
{
    //display message to user that accelerometer is not available
}

When you test the application at this point, you will not see your sphere unless your developer machine has an accelerometer in place, which I doubt

So to properly test it, you should debug your application on your mobile phone, now if you are on Flash CS5 you can use Device Central to simulate the normal behavior of  a mobile phone, Flash Builder “Burrito” users can deploy and debug directly from the Flash Builder Interface, to do that, just simply create a new Run configuration and setup as following.

When debugging the application on your phone you should now be able to see the sphere you placed in stage.

Next on let’s move on to the usage of the Accelerometer API.

To move our sphere, we simply need to take the accelerometers x & y event, have a look at the code below:

protected function onAccelUpdate( event:AccelerometerEvent ):void
{
     _targetX = event.accelerationX * _factor;
     _targetY = event.accelerationY * _factor;
}
 
protected function moveSphere(event:Event):void
{
      _sphere.x -= _targetX;
      _sphere.y += _targetY;
}

If you now test your applcation on your device or in Device Central you should see your sphere moving around on your screen.
As you see every time an update of accelerometer is being dispatched the new position is being saved in the _targetX & _targetY variable, thanks to the EnterFrame we move our sphere around the stage.

Here the complete code for you to review:

package
{
	import flash.display.Bitmap;
	import flash.display.Sprite;
	import flash.display.StageAlign;
	import flash.display.StageScaleMode;
	import flash.events.AccelerometerEvent;
	import flash.events.Event;
	import flash.sensors.Accelerometer;
 
	public class AcceleroBall extends Sprite
	{
		[Embed(source="sphere.png")]
		private var sphereClass:Class;
 
		private var _sphere			:Bitmap;
		private var _factor			:uint			= 50;
 
		private var _accelerometer		:Accelerometer;
		private var _targetX			:Number;
		private var _targetY			:Number;
 
		public function AcceleroBall()
		{
			setup();
		}
 
		protected function setup():void
		{
			if ( Accelerometer.isSupported )
			{
				_accelerometer = new Accelerometer();
				_accelerometer.addEventListener( AccelerometerEvent.UPDATE, onAccelUpdate );
 
				_sphere = new sphereClass();
				_sphere.scaleX = _sphere.scaleY = .2;
				addChild( _sphere );
 
				addEventListener(Event.ENTER_FRAME, moveSphere );
			}
			else
			{
				//display message to user that accelerometer is not available
			}
		}
 
		protected function onAccelUpdate( event:AccelerometerEvent ):void
		{
			_targetX = event.accelerationX * _factor;
			_targetY = event.accelerationY * _factor;
		}
 
		protected function moveSphere(event:Event):void
		{
			_sphere.x -= _targetX;
			_sphere.y += _targetY;
		}
	}
}

Now it’s up on you to create the boundaries, some holes on the floor, and there you go you have your first Flash Game.

If you have questions, don’t hesitate to comment on this post.

I’ve been lately working on a Multitouch Kiosk Project, in the upcoming days, I’ll be posting some of the quick hints I think they are worth sharing, some of them are simply good to know, others are braintwisting challenges I faced during the development.

Today, I would like to show you how to suppress certain Keyboard Events, let’s say you setup a kiosk application where the keyboard has to stay attached to the computer and available to the users, there are two ways you can prevent the application to be closed by a kiosk visitor:

A) You take hammer and hit the ESC key out of the keyboard
B) You write a simple small function that will take care of it.

I know I know option A is more fun, but we prefer going with option B.

So let’s have a look what we need to do:
1. As soon as our application starts we need to tell our application to go full screen interactive and add an eventlistener for Event.CLOSE and KeyboardEvent.KEYDOWN.
2. When the user tries to exit the application by either trying a key combination or CMD+Q (Win: ALT+F4) these events will popup and do whatever you wrote in the callback, this is how it should look like:

addEventListener( KeyboardEvent.KEYDOWN, onKeyDown );
addEventListener( Event.CLOSING, onClose );
 
private function onKeyDown( e:KeyboardEvent ):void
{
      e.preventDefault();
}
 
private function onClose( e:Event ):void
{
      e.preventDefault();
}

Yep the magic happens with the preventDefault() method, as it says it prevents the default action to happen. Additionally you could assign an if statement to the onKeyDown event where you listen for a specific combination of keys so you can really close the application.

I’ve been lately working on a Multitouch Kiosk Project, in the upcoming days, I’ll be posting some of the quick hints I think they are worth sharing, some of them are simply good to know, others are braintwisting challenges I faced during the development.

To start off I would like to show you people how to go FullScreen on Startup of your application, before I show you how that works, let me tell you one very important thing:
Going fullscreen rightaway without any user interaction is ONLY available within Adobe AIR, don’t try this with a pure AS3 or a Flex Project as this will not work!

Why? Security! People visiting a website shouldn’t be capped by a website taking over the whole screen without them wanting to do so, in AIR you create an application that a user will need to install to be able to run it, therefore other security aspects.

Enough of gray theory, let’s have a look how to do this very complicated task

//default fullscreenmode
stage.displayState = StageDisplayState.FULL_SCREEN;
 
//fullscreen mode with interactivity
stage.displayState = StageDisplayState.FULLSCREEN_INTERACTIVE;
 
//going back to normal screen
stage.displayState = StageDisplayState.NORMAL;

Yep that is all you need, in a typical AIR Application you would add an EventListener to your application where when creation has been completed it should call up the method above.

Example of AS3 application:

public function myApp()
{
        stage.displayState = StageDisplayState.FULL_SCREEN;
	subs = gridSize-1;
 
	particles = new Vector.>();
	_attractions = new Vector.;
	s = new ParticleSystem(new Vector3D(0,0.2, 0), .01);
 
	_attractor = s.makeParticle( .8, new Vector3D(0,4,-0.2 ) );
 
	var tmp_bm:Bitmap = new Img() as Bitmap;
	texture = tmp_bm.bitmapData;
}

You are in need of a simple video player, iightweight and easy to use?
You think OSMF is too complicated, let me correct you and present you the LightVideoElement Class.

Simple to use, quickly up and running and all needed “basic” features available.
It’s even a default in OSMF, I actually wonder why no one has written about it yet, it’s really easy to use and you can do all the basic things with it that a videoplayer needs to support nowadays and on top of it, it’s only 10k when compiled.

I’ve been using it for the last 2 projects I’ve made, and I couldn’t be happier, let’s have a quick look on how to use it:

_mediaPlayerSprite		= new MediaPlayerSprite();
_mediaPlayerSprite.graphics.beginFill(0x000000, 1 );
_mediaPlayerSprite.graphics.drawRect(0,0,640,360);
_mediaPlayerSprite.graphics.endFill();
 
_videoElement			= new LightweightVideoElement();
_videoElement.resource		= new URLResource( "pathtoyourvideo.flv" );
_videoElement.smoothing		= true;
 
addChild( _mediaPlayerSprite );
_mediaPlayerSprite.media		= _videoElement;

That’s it, no I’m not joking this is really it, you don’t need anything else to simply play a video,  now you might be asking yourself, well that’s cool but how can I control the playback? It’ easy and very intuitive, basically you only need to access the mediaplayer instance which is integrated into the _mediaPlayerSprite, there all public methods like play, pause, stop, events and so on are available for you to use. take a look at some of the functions i implemented to be able to control videoplayback.

public function play():void
{
	_mediaPlayerSprite.mediaPlayer.play();
}
 
public function pause():void
{
	_mediaPlayerSprite.mediaPlayer.pause();
}
 
public function stop():void
{
	_mediaPlayerSprite.mediaPlayer.stop();
}
 
public function get currentTime():int
{
	return _mediaPlayerSprite.mediaPlayer.currentTime;
}
 
public function get videoDuration():int
{
	return _mediaPlayerSprite.mediaPlayer.duration;
}

See, simple, easy and lighting fast.
But keep in mind that the LightWeightVideoElement has limited support, you can play every kind of flash supported videos, you can do everything a basic player needs to do, but as soon you start using SerialElements, Parallel elements and so on, then you should switch back to the default setup.
As usual you can get all the information and documentation from the official OSMF site.

You might have read on one of my previous tweets, where I was screaming about using “special” characters in Flash, with “special” I mean arabic, cyrillic, hebrew, chinese simplified and traditional, as well japanese.

I know,  I know, there is TLF (Text Layout Framework) that handles the whole text, but I’m talking about embedding the font, did you knew that the complete chinese Unicode range helds something around 20’000 characters? You might think so what? Let me tell you that the complete chinese character range is over 7MB big!!! Do you really want to let your viewers download a 7MB file just for the font? No.

So I’ve created a quick app that will enable you to read out the UTF code from the text you need to use, with it you can specifically embed only the characters you need and take the file size down to a minimum. Now there is only a downside of this method, if the textual content changes a day, you need to again import the new characters.
Apart from that, I haven’t seen any bad things about this implementation.

At the end of this post you will find an useful small tool to get all the needed characters.

As an example below with this line you are embedding a font only containing numerals typing 1234567890 will give you a range from U+0030 to U+0039

Embed(source="font_file_name", fontName="font_name", mimeType="application/x-font-truetype", unicodeRange="U+0030-U+0039,U+002E")]

So let’s assume you would like to write this: “Nemusíte oči vidět, musíte vidění” which means “You don’t need eyes to see, you need vision” and only embed the needed characters, you would embed your font like this

Embed(source="font_file_name", fontName="font_name",  mimeType="application/x-font-truetype",  unicodeRange="U+004e, U+0065, U+006d, U+0075, U+0073, U+00ed, U+0074, U+0065, U+0020,  U+006f, U+010d, U+0069, U+0020, U+0076, U+0069, U+0064, U+011b, U+0074,  U+002c, U+0020, U+006d, U+0075, U+0073, U+00ed, U+0074, U+0065, U+0020,  U+0076, U+0069, U+0064, U+011b, U+006e, U+00ed")]

If you don’t know how to use this kind of font embedding, have a read here:

http://soledadpenades.com/2008/10/21/embedding-fonts-in-actionscript-3-using-flex-sdk/

Test ride it your self and have fun

Last week I had to do something that I never thought of, let me present you the case:

First of all we have a multiline, word-wrapped textfield in AS3, the text is picked up from an external XML file and gets styled with a CSS stylesheet, the textfield CAN have one line or multiple lines (depending on the translation and the language used), if the text is only an one-liner, the graphic (a simple small gray arrow) needs to be placed after the text in the middle of the first line, so you are able to visualize this, think about a standard <li> tag where you get the black dot, in my case just at the other side eg. at the end fo the line. have a look at the Example for a visual clarification what I want to achieve.

Basically a simple task, you grab the textlength add the gutter and margin to it and place the small arrow at that position.. but what do you do when the text goes multine and word wraps automatically?
After doing some experiments, I’ve came up with a simple yet appropriate solution for this.
Let’s start with a simple text field, containing some text and setup for multiline and wordwrapping.

var tf:TextField = new TextField();
tf.text = "Lorem Ipsum is simply dummy text of the printing and typesetting industry.";
tf.width = 100;
tf.multiline = true;
tf.wordWrap = true;
addChild( tf );

This will display a simple textfield without any formatting with 5 lines of content. Why did I set a width value on my textfield? Well without it, the textfield would just be as wide as the text, resulting in a single line text, and that’s not what we want.

Now we create a simple square / dot / arrow whatever you like acting as a marker for the end of line, so you can visualize what’s happening, I’ve created a small rectangle like this:

var rect:Sprite = new Sprite();
rect.graphics.beginFill(0xff0000);
rect.graphics.drawRect(0,0,10, 2);
rect.graphics.endFill();
addChild( rect );

Simple rectangle, doesn’t need much of an explanation, maybe you asking yourself why I’ve set it at x & y 0? Although I could position the rectangle right at the proper position I always preferred to use the setters of it so I rather create all my shapes/graphs at 0,0 and move them with myShape.x = 100, it makes things more obvious to read and you find it much quicker then doing directly on the drawRect() method.

Next up let’s have a look at our class that returns the requested values.

public class StringUtil
{
	private static var _lastChar		:TextLineMetrics;
	private static var _x			:int;
	private static var _y			:int;
 
	private static var _gutter		:int = 2;
 
	public static function getEndOfLine( tf:TextField, line:int ):Point
	{
		_lastChar 	= tf.getLineMetrics(line);
		_x		= tf.x + _lastChar.width + _gutter;
		_y		= _lastChar.height * line  + _lastChar.ascent;
 
		return new Point( _x, _y );
	}
}

What we are doing here is rather simple then you think. First we pass the textfield and the desired line to our static function, then using the getLineMetrics() method we return the desired line’s metrics, this can now be used to set an x and y position of the to be returned Point(). as you see at the _x value, I’m just telling it to add the textfields x position to the width of the requested line, at the end we add the gutter value for the textfield.
The vertical position is another story, here we need to get the height of the desired line and multiply with it. this has the reason that there is no method available to get the proper y position of the line, so by multiplying the textheight with the desired line you get the proper y position of it. After that calculation we add the _lastCahr.ascent property of the line, asking what ascent? Take a look at the image below for more information about it but basically it’s just the length of the baseline to the top of the line height in pixels, so exactly the middle of our text.

Have a look at the image below for a nice and clean overview about the gutter of a flash textfield as well about the other properties a textfield has.

Something you should also be aware of is that the width of the text line is relative to the textfield width, but you need to subtract the gutter width of 4 pixels (2 pixels on each side ).

Now that our class is available let’s take a look at how I used it for this example.

var point:Point = StringUtil.getEndOfLine( tf, tf.numLines - 1 );
rect.x = point.x;
rect.y = point.y;

What we are doing here is nothing else then creating a new Point based on the position returned by our class, passing the textfield and specially since I want to have the rectangle on the LAST line I just ask for the textfields number of lines – 1.

When running this example above you should see the small red rectangle on the last line of our textfield. yay!!!

You can download the StringUtil class here: StringUtil.as
Hope this serves you as well as it served me last week, and don’t forget to leave a comment if you have any questions about it.

Last week while working on the interface for my new upcoming library I needed a way to save some data on the users computer, altough I’m working with AIR I could easily save an xml or a txt file to the users local computer, but as soon as I would start writing a pure as3 project I would have to rewrite it again, as I can’t be sure that the client will have Flash Player 10 or even the rights to save to it’s local harddisk, some people working at bigger companies are not allowed to save anything to their local harddisk due to security rights.

The solution for this is simple yet effective, you need to use SharedObjects aka. Cookies in Flash.

Shared Objects can do the following:

• Maintain Local Persistence: Saves data locally on the users drive, for example you could save the last application state or the score of the last game, create a local highscore list and many many more applications for local use.
• Store and Share Data on FMS: Basically the same as before, but with the difference that you saving the shared object on a flash media server. Good thing about it, it can be shared throughout multiple computers, the same user using the same application on multiple computers can save its data on a server.
• Share data in realtime: using FMS you can aswell for example save the state of a multiuser application saving the current state of the applcation, every new user will get the current state based on the shared object

More information about Shared Objects can be found HERE

Let me show you a few lines of code and explain what you can do with it.

The most basic example is how to write data into a shared object.

var _so:SharedObject;
_so = SharedObject.getLocal("myLocalData");
_so.data.firstname = "myfirstname";
_so.data.lastname = "mylastname";
_so.data.age = "30";
_so.flush();

In the example above we create a new variable called _so of the type SharedObject, after that we use the getLocal() method to create the shared object, if no shared object does not already exist it will be created. if the call fails or the parameters passed along are invalid, flash throws an exception. Calling the flush() method the data will be saved to the users local harddisk.

Next up lets see how you can read from a persistent shared object.

var _so:SharedObject;
_so = SharedObject.getLocal("myLocalData");
trace( _so.data.firstname); //traces myfirstname
trace(_so.data.lastname); // traces mylastname
trace(_so.data.age); // traces 30

This time we do basically the same as before, but instead of saving data we call data, when calling _so.data.age you are going to grab the sharedobjects property named age which results in 30.

If you rather prefer to save SharedObjects to an FMS, you can use it this way:

var _nc:NetConnection;
var _so:SharedObject;
 
_nc = new NetConnection();
_nc.connect("rtmp://yourFMSserver/yourAppName");
_so = SharedObject.getRemote("myRemoteData", nc.uri, false);
_so.connect( nc );
_so.setProperty( "names", {firstame:myfirstname, lastname:myLastname} );
_so.setProperty( "age", {"30"} );

This time we create a new NetConnection to the Flash Media Server and it’s application, calling the getRemote() method acts the same as using the getLocal() method, but you also need to pass the netconnections URI to be able to save the the sharedobject remotely.
Differently from the local version we use the setProperty() method to save data on the remote Shared Object.

These are the basics for handling Shared Objects, if you have any further questions just drop me a line and I might be able to help you out.

Facebook.. Could you live without facebook nowadays? Sometimes I’m happy when I don’t get anything on facebook, just to have a bit of peace and quiet of it.

Well, nevertheless, I’m writing this article because I’ve seen this post on the Adobe Forums by dmennenoh where he asked for the possibilities of using the Facebook AS3 API without Flex or AIR and the possibility of uploading pictures to Facebook.

Short answer: yes, it’s possible but…. it’s not a very well documented process of achieving it.

Before we start, I would like to recommend you a few tutorials on the Adobe Developer Connection, Jeanette Stallons wrote a whole series about the usage of the Facebook AS3 API, and it’s an absolute must read if you want to start developing flash applications or websites using facebook data and connectivity. First I recommend you starting with the Quick Start to get a feeling for it, after that move on to Part 1: Build and Test Locally, Part 2: Deploy on Facebook and Part 3: Deploy using Facebook Connect

First of all before we start be sure to get the newest FacebookAS3 library, be sure to download the Flash version of it. At this point the current version is Facebook_library_v3.4_flash.swc you can get newest version on the Project page.

As I prefer using MinimalComps by Keith Peters (aka. BIT-101) we are going to download his classes here. If you don’t know MinimalComps, it’s a set of components like you know from Flex or the Flash IDE, it contains the default set of components like button, textfield, textarea, but also has various interesting components like dials, calendars, knobs and much much more. I strongly recommend you read through the documentation and work through a few tutorials so you get your hands dirty with it.
Again this is not a MUST-USE, I just feel more comfortable using these then any other components.

I strongly recommend to use the deMonsterDebugger to trace events and data returned from facebook, it has a simple to use interface and is far better then the normal trace() functionality.

1. Setup
1.1 Let’s start by opening Flash Builder and creating a new Actionscript Project with the name FacebookAS3. We are not going to use any Flex Components neither any AIR methods, you could also build this in the Flash IDE, but I prefer to use Flash Builder for it’s Code Completion features and it’s the tool I prefer when coding AS3.

1.2 Import the .SWC file by right clicking on the Project name and selecting Properties, then go to Actionscript Build Path and select the Library path tab, press the Add SWC button and locate the downloaded facebook_library_flash.swc you downloaded previously. Press OK and we are ready to go.

1.3 If you using MinimalComps for the UserInterface, don’t forget to import the source to your project so you can use them properly.

1.4 If you using deMonsterDebugger to trace and debug your application, don’t forget to import the needed classes to your project src folder.

2. Login
Below you will find my main class that handles the whole login procedure of our small application.

public class Main extends Sprite
	{
		private static const API_KEY	:String				= "xxxxx";
		private static const SECRET	:String				= "xxxxx";
 
		private var _overlaySprite		:Sprite;
		private var _userInterface		:UserInterface;
		private var _photoBA			:ByteArray;
 
		private var _fb					:Facebook;
		private var _fbSession			:FacebookSessionUtil;
		private var _userData			:FacebookUser;
		private var _uid				:String;
		private var _batchCollection	:BatchCollection;
		private var _batchRun			:BatchRun;
		private var _albumArray			:Array;
		private var _uploadPhoto		:UploadPhoto;
 
		public function Main()
		{
			MonsterDebugger.trace(this, "init - Facebook integration" );
 
			stage.scaleMode = StageScaleMode.NO_SCALE;
			stage.align		= StageAlign.TOP_LEFT;
 
			_overlaySprite = new Sprite();
			_overlaySprite.graphics.beginFill(0xcccccc, 0.5 );
			_overlaySprite.graphics.drawRect( 0, 0, stage.stageWidth, stage.stageHeight );
			_overlaySprite.graphics.endFill();
			addChild( _overlaySprite );
			_overlaySprite.visible = false;
 
			_userInterface				= new UserInterface();
			_userInterface.addEventListener( Event.SELECT, uploadImage );
			addChild( _userInterface );
			_userInterface.visible = false;
			login();
		}
 
		private function login():void
		{
			_fbSession					= new FacebookSessionUtil( API_KEY, SECRET, loaderInfo );
			_fb							= _fbSession.facebook;
 
			_fbSession.addEventListener( FacebookEvent.CONNECT, connectHandle );
			_fbSession.addEventListener( FacebookEvent.WAITING_FOR_LOGIN, loginWaitHandler );
 
			_fbSession.login();
 
		}
 
		private function connectHandle( e:FacebookEvent ):void
		{
 
			if ( e.success )
			{
				_uid 					= ( e.data as GetSessionData ).uid;
 
				_batchCollection		= new BatchCollection();
				_batchCollection.addItem( new HasAppPermission( HasAppPermissionValues.PHOTO_UPLOAD ) );
				_batchCollection.addItem( new GetInfo([_uid], [GetInfoFieldValues.FIRST_NAME, GetInfoFieldValues.CURRENT_LOCATION]));
				_batchCollection.addItem( new GetAlbums() );
 
				_batchRun				= _fb.post( new BatchRun( _batchCollection ) ) as BatchRun;
				_batchRun.addEventListener( FacebookEvent.COMPLETE, batchCompleteHandler );
			}
		}
 
		private function batchCompleteHandler( e:FacebookEvent ):void
		{
			if ( e.success )
			{
				var results:Array = ( e.data as BatchResult ).results;
 
				var hasPermission:BooleanResultData = results[0];
				var getInfoResult:GetInfoData = results[1];
				var getAlbumsResult:GetAlbumsData = results[2];
 
				if ( !hasPermission.value )
				{
					MonsterDebugger.trace(this, "no permission" );
					getPermissions();
				}
 
					/*_userData = getInfoResult.userCollection.getItemAt(0) as FacebookUser;
					_userInterface.username = _userData.first_name + _userData.last_name;
					_userInterface.albumList = getAlbumsResult.albumCollection.toArray();*/
 
			}
 
		}
 
		private function getPermissions():void
		{
			_fb.grantExtendedPermission( ExtendedPermissionValues.PHOTO_UPLOAD );
		}
 
		private function uploadImage( e:Event ):void
		{
			_uploadPhoto = new UploadPhoto(_userInterface.snapshot);
			_fb.post(_uploadPhoto);
		}
 
		private function loginWaitHandler( e:FacebookEvent ):void
		{
			_overlaySprite.visible = true;
			_overlaySprite.addEventListener( MouseEvent.CLICK, confirmConnect );
		}
 
		private function confirmConnect( e:MouseEvent ):void
		{
			_overlaySprite.visible = false;
			_userInterface.visible = true;
			_overlaySprite.removeEventListener( MouseEvent.CLICK, confirmConnect );
			_fbSession.validateLogin();
		}
	}

Let’s take a look at what’s happening here, first of all we create instances of the facebook and the facebooksessionutil classes, those are going to help using Facebook throughout the whole application.
We setup an overlaysprite (this could also be a simple button or an alert panel) that will let us know when the user came back from the facebook login page. When the overlaysprite is clicked we validate the login and enable our userinterface. When the user is connected successfully to the application we start our BatchCollection to make multiple calls to FB, We check if the user has allowed permission to upload pictures, get his basic information like id, name and so on, and also get the album list from his profile (currently not working due to API bug)
When the batch is completed we assign the result to various variables and check the status of the extended permission if this is false, then we ask the user to confirm the permission so we are able to upload pictures, the getPermission() method.
After that we are ready to move on to our interface.

In this example I’m not going to create a seamless experience with Facebook that you know from other applications mostly on Mobile Phones, that involves a bunch of HTML and Javascript scripting and is covered on Jeanette Stallons Part 3: Deploy using Facebook Connect

3. Interface (UserInterface.as)
Next up we are going to create a simple interface so you can preview the webcam image and take a snapshot, we also going to create a small logger window so we get informed about what’s going on without having to switch to the deMonsterDebugger to view the status. Therefore I’m going to create a custom class named UserInterface which will have the visual assets and placeholders for the data received.

Below the Userinterface.as class:

public class UserInterface extends Sprite
	{
		private var _video			:Video;
		private var _camera			:Camera;
 
		private var _bitmap			:Bitmap;
		private var _bitmapData			:BitmapData;
 
		private var _snapshotBA			:ByteArray;
 
		private var _pushButton			:PushButton;
 
		private var _albumArray			:Array;
		private var _albumList			:List;
 
		public function UserInterface()
		{
			_camera				= Camera.getCamera();
			_camera.setMode( 640, 480, 25, true );
			_video				= new Video( _camera.width / 2, _camera.height / 2 );
			_video.attachCamera( _camera );
			addChild( _video );
 
			_pushButton				= new PushButton();
			_pushButton.width			= 80;
			_pushButton.x				= _video.width - _pushButton.width;
			_pushButton.y				= _video.height + 5;
			_pushButton.label			= "CAPTURE";
			_pushButton.addEventListener( MouseEvent.CLICK, createSnapshot );
			addChild( _pushButton );
 
			_bitmapData				= new BitmapData( _camera.width / 2, _camera.height / 2 );
			_bitmap					= new Bitmap( _bitmapData );
 
		}
 
		private function createSnapshot( e:MouseEvent ):void
		{
			_bitmapData.draw( _video );
			_video.visible = false;
			addChild( _bitmap );
 
			var enc:JPGEncoder = new JPGEncoder( 80 );
			_snapshotBA = enc.encode( _bitmapData );
 
			_pushButton.removeEventListener( MouseEvent.CLICK, createSnapshot );
			_pushButton.label = "UPLOAD IMAGE";
			_pushButton.addEventListener( MouseEvent.CLICK, sendSnapshot );
		}
 
		private function sendSnapshot( e:MouseEvent ):void
		{
			dispatchEvent( new Event( Event.SELECT ) )
		}
 
		private function createList():void
		{
			_albumList			= new List( this, _video.x + _video.width + 20, _video.y, _albumArray );
			addChild( _albumList );
 
		}
 
		public function set albumList( arr:Array ):void
		{
			_albumArray = arr;
			//MonsterDebugger.trace(this, _albumArray );
			//createList();
		}
 
		public function get snapshot():ByteArray
		{
			return _snapshotBA;
		}
	}

As you see I’m creaing a Camera instance with the size of 640x480px and attaching it to a video class to be displayed on the stage at halfsize, you could also keep it the full size but I prefer working with the 320×240 format.
The Bitmap and BitmapData instances are created and create a getter to return the bytearray to our mainapplication.

4. Using the Webcam
Let’s take a quicklook what we are doing to take a snapshot of the webcam and how to prepare the image to be uploaded to Facebook. As mentioned on my previous post we take a snapshot of the webcam by creating a bitmapdata of it, then we use the JPGEncoder classes from the AS3Corelib (these are as well already inside the AS3Facebook Library) and encode them into a ByteArray.

private function createSnapshot( e:MouseEvent ):void
		{
			_bitmapData.draw( _video );
			_video.visible = false;
			addChild( _bitmap );
 
			var enc:JPGEncoder = new JPGEncoder( 80 );
			_snapshotBA = enc.encode( _bitmapData );
}

5. Choosing Album and uploading Picture
As mentioned before there is currently a bug with the AS3Facebook API 3.4, you cannot get the Albumlist from the logged in user, even if you give the application the proper extended permissions. So in our case we are just going to upload our photos to the default album, now you’re asking what’s the default album?

It’s not very clear to me as well, but basically Facebook creates a Photoalbum for every application that uploads an image to it, let’s say your application is called “APU” the user using the application will get a APU PhotoGallery folder in his profile. So choose wisely what name your application will have.

Below the upload code:

private function uploadImage( e:Event ):void
		{
			_uploadPhoto = new UploadPhoto(_userInterface.snapshot);
			_fb.post(_uploadPhoto);
		}

That’s it, the most difficult part developing applications using Facebook is barely the way the whole data communication works, the API is very stable and things work well ( let’s forget the GetAlbum bug ).
Most tutorials out there have been written for Flex or AIR, simply because it gives you the best userinterface to handle FB needs nevertheless I prefer using pure AS3.

This time I didn’t want to create a nice interface to use it, as this is solely a programming article, feel free to modify it, download it, share it, whatever you would like to do with it.

You can download the project here: Source (Flash Builder Project)

The Open Source Media Framework went live a few weeks ago with it’s first release 1.0, I already worked with various sprint versions of it, and lately created a final project using OSMF.

Something that I was missing was the capability of displaying a Sprite or Text Element inside a Serial- or Parallel-Element.
So I’ve wrote a simple class named “InteractiveDisplayObjectElementt” that will handle this need:

public class InteractiveDisplayElement extends MediaElement
{
private var displayObjectTrait:InteractiveDisplayObjectTrait;
private var _sprite:Sprite;
 
public function InteractiveDisplayElement( displayObject:Sprite=null)
{
   super();
   this.sprite = displayObject;
}
 
public function set sprite( value:Sprite ):void
{
   _sprite = value;
    updateSprite();
}
 
public function get sprite():Sprite
{
    return _sprite;
}
 
private function updateSprite():void
{
   var sprite:Sprite = new Sprite();
   sprite.addChild( _sprite );
 
   if ( displayObjectTrait == null )
   {
      displayObjectTrait = new InteractiveDisplayObjectTrait( sprite );
      addTrait( MediaTraitType.DISPLAY_OBJECT, displayObjectTrait );
   }
   displayObjectTrait.setSize( sprite.width, sprite.height );
}

Extending the MediaElement class enables you to create a visible displayelement that can be attached to any kind of OSMF container including the serial & parallel elements, this is aswell the class being used for all kind of non-loadable elements.
So basically we are passing a Sprite to our new element to be placed in it, as soon as it’s set we call up the updateSprite() method that will add the passed sprite to the displaylist and assign it to the InteractiveDisplayObjectTrait (class following below)

The second class built was the InteractiveDisplayObjectTrait, this was only to keep the structure and logic of OSMF kind of in “place”, with it you can set the size of the element separately.

internal class InteractiveDisplayObjectTrait extends DisplayObjectTrait
{
  public function InteractiveDisplayObjectTrait(displayObject:DisplayObject, mediaWidth:Number=0, mediaHeight:Number=0)
  {
    super(displayObject, mediaWidth, mediaHeight);
  }
 
  public function setSize(mediaWidth:Number, mediaHeight:Number):void
  {
     setMediaSize(mediaWidth, mediaHeight);
  }
}

With it you are now able to use simple as well complex sprites in your Composition elements, below an example of how I tested the newly built class.

...
var aniHolder:Sprite = new Sprite();
sp.addChild( aniHolder );
var ball:Sprite = new Sprite();
ball.graphics.beginFill(0xff0000,1 );
ball.graphics.drawCircle( 0, 0, 8 );
ball.graphics.endFill();
aniHolder.addChild( ball );
 
TweenMax.to( ball, 2, { x: 400, repeat:-1, yoyo:true, ease:com.greensock.easing.Bounce.easeInOut});
 
var _spriteElement2:InteractiveDisplayElement = new InteractiveDisplayElement( aniHolder );
layout							= new LayoutMetadata();
layout.left = 400;
_spriteElement2.addMetadata( LayoutMetadata.LAYOUT_NAMESPACE, layout );
_pararellElement.addChild( _spriteElement2 );
...

What do you need to know about the code above? Well as you see I’m only creating a red circle that is being added to the aniHolder sprite, with the help of tweenmax I’m animating the circle to bounce left to right and viceversa, then I create a new InteractiveDisplayElement (the class we created before) assign a layout to it and add to the ParallelElement (this could also be a serialelement or a simple mediacontainerSprite).

During Developer Week, learn about the Adobe® Flash® Platform, including Adobe® Flex®, Adobe® Flash® Builder™, Adobe® AIR®, Adobe® Flash® Player, and how it integrates with Adobe® Creative Suite® 5 technologies. This weeklong event features free, live webinars presented by Adobe technology experts. See live demos and have your questions answered by the experts during interactive Q&A sessions.

Want to attend? Nothing easier then that! Just jump over directly here:
http://www.adobe.com/cfusion/event/index.cfm?event=detail&id=1489921&loc=en_us

Ok, this just drove me nuts for a few minutes..

I’m getting the server time UNIX formatted, I was constantly trying to convert the integer to a readable date, constantly getting the wrong year (the default or zero unix year is 1970) but aren’t we living in 2009?

So for future reference and for anyone that might be searching for this.

Unix time is seconds based, Flash time is milliseconds based. got it?
So anytime you get a unix time integer you just need to multiply by 1000 to get the correct time for your Flash project.

Example:

GOOD CODE

curDate                = new Date(Number(dateXML.int * 1000));

BAD CODE

curDate                = new Date(Number(dateXML.int));

I just stumbled across this page, and I think it’s a very good starting position for people who would like to learn Flex or strengthen their knowledge, all you need is a working version of AMP and this link to include into the RSS feed of AMP.
http://sessions.adobe.com/FlexInAWeek/feed.xml

For a more detailed list of available videos and more check out this site:
http://www.adobe.com/devnet/flex/videotraining/?sdid=DXGFC